单片机入门

摘要: 通常我们网站提供的试验开发板是焊接并测试好的成品板，可以开始51单片机实验板的一系列安装与实验，如果是购买套件的网友，收到货物后请仔细核对一下元件清单。

AT89C51单片机实验开发板套件元件清单：

专门设计的全工艺电路板一块

电源部分元件：

1． 9伏左右直流插头式小电源，带插头(空载12伏)
2． 电源插座一个
3． 7805稳压芯片一个
4． 470UF/16V电源滤波电容两个
5． 0.1UF独石电容两个
6． 电源指示绿色LED一个
7． LED限流电阻560欧姆电阻一个

单片机必须部分的元件：

1． AT89C51单片机芯片一片
2． 40脚零拔插力ZIF插座一个
3． 复位用电容22UF/16V电容一个
4． 复位用电阻1K一个
5． 30P小电容2个
6． 12M晶振一个

实验部分元件：

1． 8个小红色长方形LED
2． 8位1K数码管限流排阻
3． 1个共阴两位一体化的数码管一个
4． 一个5伏电磁型蜂鸣器
5． 1个8550驱动三极管（e/b/c)
6． 3个1K三极管基极驱动电阻
7． 微型轻触开关4个
8． 4位的红色拨码开关一个
9． 2个12伏JQC-3F继电器（一组常开转常闭）
10．2个IN4148防反峰二极管
11. 2个8050驱动三极管(e/b/c)
12. 2个继电器状态指示红色发光二极管

1． 原装进口MAX232芯片一片
2． 5.1K上拉电阻两个
3． 10UF电容4个
4． 塑封一体化红外线接收头一个
5． AT24C02存储器芯片一片
6． 220UF滤波电容一个
7． 0.1UF电容一个
8． 32个按键的红外遥控手柄一个
9． 串口通讯电缆一根

   对于购买成品板的网友拿到的是经过焊接好的产品，并且经过测试完好，不管是购买套件还是成品单片机实验开发板的网友得到的单片机中都已经烧录了一个测试程序，测试程序主要是用来测试51试验板的单片机和相关外围元件的好坏，如果这个程序能够顺利运行，说明实验板的各方面都很正常。


    测试程序对于初学者来说可能比较复杂,但是也是由网站上几个小程序组合而成的，初学者可以通过后面教程的学习来掌握这段程序。

    这个测试程序的功能是：接通电源后P0口的八个发光二极管依次从下往上点亮，然后蜂鸣器鸣叫一声，两个继电器轮流动作一次，数码管的个位显示8，再换成十位显示8，然后不断循环，如果这时按下红外遥控器的按键时，蜂鸣器立即发出“滴滴滴”的提示音，同时将这个按键的键值通过串口在电脑屏幕上显示出来（需要运行串口调试软件）通过这个程序可以判断单片机实验开发板的各个部分的硬件和软件都是完好的，具体的源程序如下：

   ;请注意晶振频率为12M时,请根据提示修改相应的行(共5处)
   ORG 0000H
       AJMP MAIN;转入主程序
       ORG 0003H;外部中断P3.2脚INT0入口地址
       AJMP INT;转入外部中断服务子程序（红外遥控解码程序）
;以下为主程序进行CPU中断方式设置
MAIN:  LCALL YS3;等待硬件上电稳定
       SETB EA;打开CPU总中断请求
       SETB IT0;设定INT0的触发方式为脉冲负边沿触发
       SETB EX0;打开INT0中断请求
       MOV SCON,#50H;设置成串口1方式
       MOV TMOD,#20H;波特率发生器T1工作在模式2上
       MOV PCON,#80H;波特率翻倍为2400x2=4800BPS
       ;MOV TH1,#0F3H;预置初值 晶振为11.0592M时,请用 ; 注释掉此行
       ;MOV TL1,#0F3H;预置初值 晶振为11.0592M时,请用 ; 注释掉此行
   MOV TH1,#0F4H;预置初值 晶振为12M时,请用 ; 注释掉此行
   MOV TL1,#0F4H;预置初值 晶振为12M时,请用 ; 注释掉此行
       SETB TR1;启动定时器T1
;以上完成串口通讯初始化设置

START: MOV P1,#01111111B
       LCALL DELAY
       MOV P1,#10111111B
       LCALL DELAY
       MOV P1,#11011111B
       LCALL DELAY
       MOV P1,#11101111B
       LCALL DELAY
       MOV P1,#11110111B
       LCALL DELAY
       MOV P1,#11111011B
       LCALL DELAY
       MOV P1,#11111101B
       LCALL DELAY
       MOV P1,#11111110B;P1口的LED循环由下往上点亮一次,延时约250毫秒
       LCALL DELAY
       MOV P2,#11011111B;蜂鸣器鸣响一声
       LCALL DELAY
       MOV P2,#11101111B;继电器J1吸合一次
       LCALL DELAY
       MOV P2,#11110111B;继电器J2吸合一次
       LCALL DELAY
       MOV P0,#0FFH
       MOV P2,#01111111B;数码管个位显示8
       LCALL DELAY
       MOV P0,#0FFH
       MOV P2,#10111111B;数码管十位显示8
       LCALL DELAY
       AJMP START;反复循环

;以下为进入P3.2脚外部中断子程序，也就是解码程序
INT:   CLR EA;暂时关闭CPU的所有中断请求
       MOV R6,#10
SB:    ACALL YS1;调用882微秒延时子程序
       JB P3.2,EXIT;延时882微秒后判断P3.2脚是否出现高电平如果有就退出解码程序
       DJNZ R6, SB;重复10次，目的是检测在8820微秒内如果出现高电平就退出解码程序
;以上完成对遥控信号的9000微秒的初始低电平信号的识别。
       JNB P3.2, $;等待高电平避开9毫秒低电平引导脉冲
       ACALL YS2;延时4.74毫秒避开4.5毫秒的结果码
       MOV R7,#26;忽略前26位系统识别码

JJJJA: JNB P3.2,$;等待地址码第一位的高电平信号
       LCALL YS1;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
       MOV C,P3.2;将P3.2引脚此时的电平状态0或1存入C中
       JNC UUUA;如果为0就跳转到UUUA
       LCALL YS3;检测到高电平1的话延时1毫秒等待脉冲高电平结束
UUUA:  DJNZ R7,JJJJA

       MOV R1,#1AH ;设定1AH为起始RAM区
       MOV R2,#2;接收从1AH到1BH的2个内存,用于存放操作码和操作反码
PP:    MOV R3,#8;每组数据为8位

JJJJ:  JNB P3.2,$;等待地址码第一位的高电平信号
       LCALL YS1;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
       MOV C,P3.2;将P3.2引脚此时的电平状态0或1存入C中
       JNC UUU;如果为0就跳转到UUU
       LCALL YS3;检测到高电平1的话延时1毫秒等待脉冲高电平结束
UUU:   MOV A,@R1;将R1中地址的给A
       RRC A;将C中的值0或1移入A中的最低位
       MOV @R1,A;将A中的数暂时存放在R1数值的内存中
       DJNZ R3,JJJJ;接收满8位换一个内存
       INC R1;对R1中的值加1，换下一个RAM
       DJNZ R2,PP ;接收完8位数据码和8位数据反码，存放在1AH/1BH中

       MOV A,1AH
       CPL A;对1AH取反后和1BH比较
       CJNE A,1BH,EXIT;如果不等表示接收数据发生错误,放弃

       MOV P1,1AH;将按键的键值通过P1口的8个LED显示出来!
       MOV A,1AH;将红外遥控器具体按键的键值发送到串口去
       MOV SBUF,A;通过串口在电脑屏幕上显示出来

       CLR P2.5;蜂鸣器鸣响嘀嘀嘀的声音，表示解码成功
       LCALL YS2
       LCALL YS2
       LCALL YS2
       SETB P2.5;蜂鸣器停止
EXIT:  SETB EA ;允许中断
       RETI ;退出解码子程序

YS1:   MOV R4,#20 ;（占用R4/R5）延时子程序1，精确延时882微秒
D1:    ;MOV R5,#20  ;晶振为11.0592M时,请用 ; 注释掉此行
   MOV R5,#19  ;晶振为12M时,请用 ; 注释掉此行
       DJNZ R5,$
       DJNZ R4,D1
       RET

YS2:   MOV R4,#10 ;（占用R4/R5）延时子程序2，精确延时4740微秒
D2:    ;MOV R5,#235  ;晶振为11.0592M时,请用 ; 注释掉此行
       MOV R5,#216  ;晶振为12M时,请用 ; 注释掉此行
   DJNZ R5,$
       DJNZ R4,D2
       RET

YS3:   MOV R4,#2;（占用R4/R5）延时程序3，精确延时1000微秒
D3:    ;MOV R5,#248   ;晶振为11.0592M时,请用 ; 注释掉此行
   MOV R5,#228  ;晶振为12M时,请用 ; 注释掉此行
       DJNZ R5,$
       DJNZ R4,D3
       RET

DELAY: MOV R1,#08H;（占用R1/R2/R3）延时子程序，12M晶振延时约250毫秒
L3:    MOV R2 ,#0FAH
L1:    MOV R3 ,#0FAH
L2:    DJNZ R3 ,L2
       DJNZ R2 ,L1
       DJNZ R1 ,L3
       RET
       END